75 lines
2.3 KiB
Plaintext
75 lines
2.3 KiB
Plaintext
// Root for the rules
|
|
?root: sequence -> start
|
|
sequence: (pitch_class | dur_change | oct_mod | oct_change | WS | chord | cycle | random_integer | random_pitch | random_percent | range | list | repeated_list | lisp_operation | list_op | subdivision | eval | euclid | repeat)*
|
|
|
|
// Pitch classes
|
|
pitch_class: prefix* pitch
|
|
prefix: (octave | duration_chars | escaped_decimal | escaped_octave)
|
|
pitch: /-?[0-9TE]/
|
|
escaped_decimal: "<" decimal ">"
|
|
escaped_octave: /<-?[0-9]>/
|
|
octave: /[_^]+/
|
|
|
|
// Chords
|
|
chord: pitch_class pitch_class+
|
|
|
|
// Valid as integer
|
|
?number: SIGNED_NUMBER | random_integer | cyclic_number
|
|
cyclic_number: "<" number (WS number)* ">"
|
|
|
|
// Repeats
|
|
repeat: "[:" sequence ":" [number] "]"
|
|
|
|
// List
|
|
list: prefix* "(" sequence ")"
|
|
repeated_list: prefix* "(:" sequence ":" [number] ")"
|
|
|
|
// Right recursive list operation
|
|
list_op: list (operator (list | number))+
|
|
operator: /([\+\-\*\/%]|<<|>>)/
|
|
|
|
// Euclidean cycles
|
|
euclid: list euclid_operator list?
|
|
?euclid_operator: /<[0-9]+,[0-9]+(,[0-9])?>/
|
|
|
|
// TODO: Support randomization etc.
|
|
//euclid_operator: (">" | "<") number "," number ["," number] (">" | "<")
|
|
|
|
// Lisp like list operation
|
|
lisp_operation: "(" operator WS sequence ")"
|
|
|
|
// Durations
|
|
duration_chars: dotted_dur+
|
|
dotted_dur: dchar dot*
|
|
decimal: /-?[0-9]+\.[0-9]+/
|
|
dchar: /[mklpdcwyhnqaefsxtgujzo]/
|
|
dot: "."
|
|
|
|
// Subdivision
|
|
subdivision: "[" subitems "]"
|
|
subitems: (pitch_class | WS | chord | cycle | subdivision)*
|
|
|
|
// Control characters modifying future events
|
|
oct_mod: octave WS
|
|
oct_change: escaped_octave WS
|
|
dur_change: (decimal | char_change)
|
|
char_change: dchar_not_prefix+
|
|
dchar_not_prefix: /([mklpdcwyhnqaefsxtgujzo](\.)*)(?!\d)/
|
|
|
|
// Generative rules
|
|
random_integer: /\(-?[0-9]+,-?[0-9]+\)/
|
|
range: /-?[0-9]\.\.-?[0-9]/
|
|
cycle: "<" sequence ">"
|
|
random_pitch: "?"
|
|
random_percent: "%"
|
|
|
|
// Rules for evaluating clauses inside {}
|
|
// TODO: Support for parenthesis?
|
|
eval: "{" operation "}"
|
|
operation: atom (operator atom)+
|
|
atom: (number | DECIMAL)
|
|
|
|
%import common.NUMBER
|
|
%import common.SIGNED_NUMBER
|
|
%import common.DECIMAL
|
|
%import common.WS |